Funções de string no Jitterbit Integration Studio

Funções de string são o mecanismo para manipulação de strings em scripts.

CountSubString

Declaração

int CountSubString(string str, string subStr)

Sintaxe

CountSubString(<str>, <subStr>)

Parâmetros obrigatórios

• str: Uma string a ser pesquisada
• subStr: A string para pesquisar com

Descrição

Retorna o número de vezes que uma substring aparece em uma string.

Exemplos

CountSubString("Mississippi", "iss"); // Returns 2

DQuote

Declaração

string DQuote(string str)

Sintaxe

DQuote(<str>)

Parâmetros obrigatórios

• str: Uma string a ser colocada entre aspas duplas

Descrição

Coloca uma string entre aspas duplas e retorna o resultado. Aspas duplas incorporadas não são escapadas.

Exemplos

DQuote("any str"); // Returns ""any str""

DQuote('any "text" str');
// Returns ""any "text" str"" -- note that the embedded double quotes are not escaped

Format

Declaração

string Format(string formatStr, type de)

Sintaxe

Format(<formatStr>, <de>)

Parâmetros obrigatórios

• formatStr: A string de formato para ser usado ao formatar a string
• de: Um elemento de dados; se necessário, será convertido em uma string antes de ser formatado

Descrição

Retorna uma string no formato especificado por uma string de formato.

A especificação do formato é a mesma usada nas funções de data e hora; veja sua seção sobre strings de formato. É semelhante à especificação de formato printf da biblioteca C padrão.

Esta função pode ser usada para definir o formato de saída para um alvo. É útil quando o formato de saída padrão do Jitterbit para um tipo de dado (como data ou double) não é o desejado. A chamada para o Format function deve ser a última chamada em uma fórmula de mapeamento para que seja o valor mapeado.

Exemplos

Format("'%5d'", 2); // Returns "'    2'"

Index

Declaração

int Index(string str, string subStr[, int n])

Sintaxe

Index(<str>, <subStr>[, <n>])

Parâmetros obrigatórios

• str: Uma string a ser pesquisada
• subStr: A string para pesquisar com

Parâmetros opcionais

• n: A instância específica de interesse se mais de uma correspondência

Descrição

Retorna a posição de uma sub-string dentro de uma string.

Em casos onde a sub-string aparece mais de uma vez na string principal, o terceiro argumento (n) é usado para determinar qual instância específica da sub-string é de interesse.

• Se n < 0, a contagem de instâncias começa do final da string principal.
• Se |n| >o número máximo de vezes que a substring aparece na string principal, a função retorna -1.

Caso contrário, a função retorna a posição do primeiro caractere da substring dentro da string principal (começando na posição 0).

Casos especiais a serem considerados:

• n = 0 retorna o mesmo resultado que n = 1

• Se subStr é uma string vazia (""):

  • n >= 0 sempre retorna 0

  • n < 0 sempre retorna Length(str)

Exemplos

Index("Mississippi", "s"); // Returns 2
// When called with only two arguments
// the optional third argument defaults to 1,
// resulting in the index of the first match being returned

Index("Mississippi", "iss", 3); // Returns -1
// Searching for the 3rd instance of "iss" within Mississippi

Index("Mississippi", "si", 2); // Returns 6
// The 2nd instance of the sub-string
// "si" starts at position 6 as the
// first letter "M" starts at position 0

Index("Mississippi", "", 1); // Returns 0
Index("Mississippi", "", -1); // Returns 11

IsValidString

Declaração

bool IsValidString(string str)

Sintaxe

IsValidString(<str>)

Parâmetros obrigatórios

• str: Uma string a ser validada

Descrição

Retorna true se cada caractere em uma string for válido. Caracteres válidos são códigos ASCII de 32 a 126 inclusive e qualquer um dos caracteres linefeed (LF), carriage return (CR) ou aba (TAB).

Exemplos

IsValidString("An Invalid String™");
// Returns 0 (false), as the trademark symbol in this font is a code greater than 128

IsValidString("A Valid Broken
String");
// Returns 1 (true)

Left

Declaração

string Left(string str, int n)

Sintaxe

Left(<str>, <n>)

Parâmetros obrigatórios

• str: Uma sequência
• n: O número de caracteres da extremidade esquerda a ser retornado

Descrição

Retornos n caracteres de uma string, contando da esquerda (o começo) de uma string.

Veja também o Mid e Right funções.

Exemplos

Left("01234567890", 4);
// Returns "0123"

LPad

Declaração

string LPad(string str, int n)

Sintaxe

LPad(<str>, <n>)

Parâmetros obrigatórios

• str: Uma sequência
• n: O número de caracteres da extremidade esquerda a serem retornados

Descrição

Adiciona espaços à esquerda (o início) de uma string até que a string contenha n caracteres. Strings contendo n ou mais caracteres são truncados para n personagens.

LPad(str, -n)é o mesmo que RPad(str, n). Veja o RPad função.

Exemplos

LPad("01234567", 9);
// Returns " 01234567"
// Adds one space to the left side
// of the original string

LPad("1234567890", 9);
// Returns "123456789"

LPadChar

Declaração

string LPadChar(string str, string padChar, int n)

Sintaxe

LPadChar(<str>, <padChar>, <n>)

Parâmetros obrigatórios

• str: Uma sequência
• padChar: Uma string a ser usada para preencher caracteres; se houver mais de um caractere, o primeiro caractere será usado
• n: O número de caracteres da extremidade esquerda a serem retornados

Descrição

Adiciona um caractere de preenchimento à esquerda (o início) de uma string até que a string contenha n caracteres. Strings contendo n ou mais caracteres são truncados para n personagens.

LPadChar(str, " ", n)é o mesmo que LPad(str, n). Veja o LPad função.

Exemplos

LPadChar(1234567, "0", 10);
// Returns "0001234567"
LPadChar(1234567, ".0", 10);
// Returns "...1234567"

LTrim

Declaração

string LTrim(string str)

Sintaxe

LTrim(<str>)

Parâmetros obrigatórios

• str: Uma sequência

Descrição

Remove espaços em branco (espaços, tabulações) da esquerda (início) de uma string e retorna os caracteres restantes.

Exemplos

LTrim(" Hello World!  ");
// Returns "Hello World!  "

LTrim("    Hello World!");
// Removes the leading tab character
// and returns "Hello World!"

LTrimChars

Declaração

string LTrimChars(string str, string trimChars)

Sintaxe

LTrimChars(<str>, <trimChars>)

Parâmetros obrigatórios

• str: Uma string a ser cortada da esquerda (o começo)**
  
• trimChars: Uma sequência de caracteres de corte a serem correspondidos; a ordem não importa

Descrição

Remove quaisquer caracteres iniciais em uma string da esquerda (o começo) que correspondem aos caracteres de corte e retorna os caracteres restantes.

Esta função testa cada caractere inicial de uma string, começando na borda esquerda, e verifica se ele é encontrado nos caracteres de corte. Se for, ele é removido e o processo é repetido até que não haja mais uma correspondência.

Isso pode ser usado para cortar caracteres diferentes dos caracteres de espaço em branco padrão, como cortar dois pontos iniciais.

Veja também o RTrimChars e TrimChars funções.

Exemplos

LTrimChars("::StartMsg :: Hello :: EndMsg::", ":");
// Returns "StartMsg :: Hello :: EndMsg::"

LTrimChars("// This is a comment", " /");
// Returns "This is a comment"

LTrimChars("// This is a comment", "/ ");
// Returns "This is a comment"

LTrimChars("// This is a comment", "/");
// Returns " This is a comment"

LTrimChars("// This is a comment", " ");
// Returns "// This is a comment"
// Returns the string unchanged as a space
// was not a leading character

Mid

Declaração

string Mid(string str, int m, int n)

Sintaxe

Mid(<str>, <m>, <n>)

Parâmetros obrigatórios

• str: Uma string da qual extrair uma sub-string

• m: A posição inicial do caractere de base zero para começar a extrair a sub-string

• n: O comprimento (número de caracteres) da sub-string a ser extraída

Descrição

Retorna uma parte de uma string, começando com o caractere na posição m por um comprimento de n personagens.

Veja também o Left e Right funções.

Exemplos

Mid("Jitterbit", 2, 3);
// Returns "tte"

Mid("01234567890", 7, 3);
// Returns "789"

// Passing the same string as an
// integer with a leading zero
// returns a different result
Mid(01234567890, 7, 3);
// Returns "890"

ParseURL

Declaração

array ParseURL(string url)

Sintaxe

ParseURL(<url>)

Parâmetros obrigatórios

• url: Uma string contendo uma URL para análise

Descrição

Analisa uma string de URL e retorna um array de valores decodificados. Os valores são marcados para que possam ser recuperados por índice ou por nome de campo.

Ao recuperar valores do resultado, o caso de um nome de campo é ignorado. Veja também o URLDecode e URLEncode funções.

Exemplos

url = "http://hostname/user?email=john1990%40example.com&name=John%20Smith";
arr = ParseURL(url);

email = arr[0];
// "email" will be john1990@example.com
email = arr["email"];
// same as previous

name = arr["name"];
// "name" will be "John Smith"
name = arr["Name"];
// Same as previous;
// case is ignored for field names

Quote

Declaração

string Quote(string str)

Sintaxe

Quote(<str>)

Parâmetros obrigatórios

• str: Uma string a ser colocada entre aspas simples

Descrição

Coloca uma string entre aspas simples e retorna o resultado. Aspas simples incorporadas não são escapadas.

Exemplos

Quote("Any string");
// Returns "'Any string'"

Quote("Ain't escaped");
// Returns "'Ain't escaped'" -- note that the embedded quote is not escaped.

RegExMatch

Declaração

int RegExMatch(string str, string exp[, type var1,... type varN])

Sintaxe

RegExMatch(<str>, <exp>[, <var1>,... <varN>])

Parâmetros obrigatórios

• str: Uma string a ser comparada com

• exp: Uma expressão regular que consiste em grupos

Parâmetros opcionais

• var1...varN: Um ou mais nomes de variáveis, a serem correspondidos às subexpressões marcadas da expressão

Descrição

Corresponde uma expressão regular com uma string de entrada, armazena as subexpressões marcadas em variáveis e retorna o número de correspondências.

Retorna o número total de subexpressões marcadas (que pode ser maior ou menor que o número de variáveis realmente fornecidas). Quaisquer correspondências adicionais que excedam o número de variáveis fornecidas são descartadas. Se não houver correspondências, -1 é retornado.

A expressão regular segue a sintaxe da biblioteca de expressões regulares Boost. É uma variação da sintaxe de expressão regular do Perl.

Caracteres Unicode, incluindo símbolos como emoji, devem ser correspondidos usando seus caracteres literais e não usando sequências de escape Unicode. Por exemplo, o intervalo "[😀-🤯]" (U+1F600 a U+1F92F) captura com sucesso o símbolo 🤔 (U+1F914) no meio.

Veja também o RegExReplace função.

Exemplos

expression = "\D*";
// Expression that matches what aren't digits.

$reg_1 = RegExMatch("123", expression);
// Returns -1 because the input string contains digits.

$reg_2 = RegExMatch("123A" ,expression);
// Returns -1 because the input string starts with digits.

$reg_3 = RegExMatch("ABC", "[a-zA-Z]*");
// Returns 0 because a match was found with without matching sub-expressions.

$reg_4 = RegExMatch("a", "[a-z]");
// Returns 0 because the single character matches what the expression expected.

$reg_5 = RegExMatch("ab", "[a-z]");
// Returns -1 because the expression does not cover the entire input string and is expecting a single character.
// Refer to the note above for additional information.

$reg_6 = RegExMatch("ab", "[a-z]+");
// Returns 0.

$reg_7 = RegExMatch("ab", "a*b", "reg_7_value");
// Returns 0.
// Does not set the global variable "$reg_7_value" because there are no sub-expressions.

$reg_8 = RegExMatch("ab", "(a*b)", "reg_8_value");
// Returns 1 because the sub-expression was matched.
// Sets the global variable "$reg_8_value" to "ab".

$reg_9 = RegExMatch("[abc]", "(\\[)(.*)(\\])", "reg_9_test", "reg_9_value");
result = $reg_9;
// Sets the global variable "$reg_9_test" to "[".
// Sets the global variable "$reg_9_value" to "abc".
// Returns 3 because the character "]" also matched the last sub-expression.
// However, as there are only two variable names, the last match is not saved to a variable.

RegExReplace

Declaração

string RegExReplace(string str, string exp, string format)

Sintaxe

RegExReplace(<str>, <exp>, <format>)

Parâmetros obrigatórios

• str: Uma string a ser pesquisada e ter quaisquer substrings correspondentes substituídas

• exp: A expressão regular na sintaxe da biblioteca de expressões regulares Boost para ser usado para corresponder a sub-strings da string

• format: Uma sequência de formato na Sintaxe de sequência de formato estendida Boost

Descrição

Substitui todas as substrings em uma string que correspondem a uma expressão, usando um formato especificado para substituir cada substring. Quaisquer seções da string que não correspondem à expressão são passadas para a string retornada inalteradas.

A expressão regular segue a sintaxe da biblioteca de expressões regulares Boost. É uma variação da sintaxe de expressão regular do Perl.

Caracteres Unicode, incluindo símbolos como emoji, devem ser correspondidos usando seus caracteres literais e não usando sequências de escape Unicode. Por exemplo, o intervalo "[😀-🤯]" (U+1F600 a U+1F92F) captura com sucesso o símbolo 🤔 (U+1F914) no meio.

A string de formato segue a Boost-Extended Format String Syntax. Se a string de formato for uma string vazia ("") então uma correspondência não produz nenhum resultado para essa sub-string.

Veja também o RegExMatch função.

Exemplos

// To remove any whitespace from a string:
RegExReplace(" t e st ss s", "\\s", "");
// Returns "testsss"

// To swap the order of sub-strings:
RegExReplace("abc(first)123(second)xyz",
             "(.*)(\\(.*\\))(.*)(\\(.*\\))(.*)",
             "\\1aaa\\4\\2\\3\\5");
// Returns "abcaaa(second)(first)123xyz"

// To pass backslashes in matches, multiple instances may be required.
// In the "r" example, three backslashes are used and then doubled.
// The first two backslashes convert into a single backslash,
// which then escapes the next backslash.
// All three backslashes are then doubled for Jitterbit script.
s = "test\\ing";  // "test\ing";
t = RegExReplace(s, "\\\\", "!");  // "test\ing" -> "test!ing"
r = RegExReplace(t, "!", "\\\\\\");  // "test!ing" ->  "test\\ing"

Replace

Declaração

string Replace(string str, string old, string new)

Sintaxe

Replace(<str>, <old>, <new>)

Parâmetros obrigatórios

• str: Uma string a ser pesquisada e as substrings correspondentes substituídas

• old: Uma string a ser usada para a correspondência

• new: Uma string a ser usada como substituição para quaisquer correspondências encontradas

Descrição

Pesquisa uma string por substrings que correspondem ao argumento "old" e substitui uma substring correspondente pelo argumento "new".

Para operações de busca e substituição mais complexas, veja o RegExReplace função.

Exemplos

Replace("Monday Tuesday", "day", "day night,");
// Returns "Monday night, Tuesday night,"

Right

Declaração

string Right(string str, int n)

Sintaxe

Right(<str>, <n>)

Parâmetros obrigatórios

• str: Uma sequência

• n: O número de caracteres da extremidade direita a serem retornados

Descrição

Retornos n caracteres de uma string, contando da direita (o fim) de uma string.

Veja também o Left e Mid funções.

Exemplos

Right("01234567890",4);
// Returns "7890"

RPad

Declaração

string RPad(string s, int n)

Sintaxe

string RPad(string s, int n)

Parâmetros obrigatórios

• str: Uma sequência

• n: O número de caracteres da extremidade direita a serem retornados

Descrição

Adiciona espaços à direita (o fim) de uma string até que a string contenha n caracteres. Strings contendo n ou mais caracteres são truncados para n personagens.

RPad(str, -n)é o mesmo que LPad(str, n). Veja o LPad função.

Exemplos

RPad("01234567",9);
// Returns "01234567 "

RPadChar

Declaração

string RPadChar(string str, string padChar, int n)

Sintaxe

RPadChar(<str>, <padChar>, <n>)

Parâmetros obrigatórios

• str: Uma sequência
• padChar: Uma string a ser usada para preencher caracteres; se houver mais de um caractere, o primeiro caractere será usado
• n: O número de caracteres da extremidade direita a serem retornados

Descrição

Adiciona um caractere de preenchimento à direita (o fim) de uma string até que a string contenha n caracteres. Strings contendo n ou mais caracteres são truncados para n personagens.

RPadChar(str, " ", n)é o mesmo que RPad(str, n). Veja o RPad função.

Exemplos

RPadChar(1234567, "0", 10);
// Returns "1234567000"

RTrim

Declaração

string RTrim(string str)

Sintaxe

RTrim(<str>)

Parâmetros obrigatórios

• str: Uma sequência

Descrição

Remove espaços em branco (espaços, tabulações) da direita (fim) de uma string e retorna os caracteres restantes.

Exemplos

RTrim(" Hello World!  ");
// Returns " Hello World!"

RTrim("Hello World!    ");
// Removes the trailing tab character
// and returns "Hello World!"

RTrimChars

Declaração

string RTrimChars(string str, string trimChars)

Sintaxe

RTrimChars(<str>, <trimChars>)

Parâmetros obrigatórios

• str: Uma corda, a ser cortada da direita (o fim)**
  
• trimChars:** Uma sequência de caracteres de corte a serem correspondidos; a ordem não importa

Descrição

Remove quaisquer caracteres finais em uma string do final que correspondem aos caracteres de corte e retorna os caracteres restantes.

Esta função testa cada caractere final de uma string, começando na borda direita, e verifica se ele é encontrado nos caracteres de corte. Se for, ele é removido e o processo é repetido até que não haja mais uma correspondência.

Isso pode ser usado para cortar caracteres diferentes dos caracteres de espaço em branco padrão, como cortar dois pontos finais.

Veja também o LTrimChars e TrimChars funções.

Exemplos

RTrimChars("::StartMsg :: Hello :: EndMsg::", ":");
// Returns "::StartMsg :: Hello :: EndMsg"

RTrimChars("// This is a comment //", " /");
// Returns "// This is a comment"

RTrimChars("// This is a comment //", "/");
// Returns "// This is a comment "

RTrimChars("// This is a comment //", " ");
// Returns "// This is a comment //"
// Returns the string unchanged as a space
// was not a trailing character

Split

Declaração

array Split(string str, string delimiter)

Sintaxe

Split(<str>, <delimiter>)

Parâmetros obrigatórios

• str: Uma string a ser dividida
• delimiter: Uma sequência de caracteres a ser correspondida como a divisão entre cada elemento da matriz

Descrição

Divide uma string usando uma string delimitadora, retornando o resultado como uma matriz.

Retorna o resultado em uma matriz de tamanho igual ao número de delimitadores mais um. Se a expressão terminar com o delimitador, o tamanho da matriz será igual ao número de delimitadores (o último valor vazio será ignorado). Se a string não contiver delimitadores, uma matriz de tamanho um será retornada contendo a string original.

Exemplos

arr = Split("Donald,Minnie,Goofy", ",");
donald = arr[0];
minnie = arr[1];
goofy = arr[2];

Split("Donald.,Minnie.,Goofy.,", ".,");
// Returns the array {Donald, Minnie, Goofy}

Este exemplo converte um endereço IP ("10.6.10.1") para um único inteiro (168167937):

// Logic: (first octet * 16777216) + (second octet * 65536) +
//   (third octet * 256) + (fourth octet)
ip = "10.6.10.1";
ipList = Split(ip, ".");
(Int(ipList[0]) * 16777216) + (Int(ipList[1]) * 65536) +
    (Int(ipList[2]) * 256) + (Int(ipList[3]));

SplitCSV

Declaração

array Split(string str[, string delimiter, int qualifier])

Sintaxe

Split(<str>[, <delimiter>, <qualifier>])

Parâmetros obrigatórios

• str: Uma string a ser dividida

Parâmetros opcionais

• delimiter: Uma sequência de caracteres a ser correspondida como a divisão entre cada elemento da matriz
• qualifier: Uma sequência de caracteres a ser correspondida como a divisão entre cada elemento da matriz

Descrição

Divide uma string formatada em CSV e retorna uma matriz com os valores individuais da coluna.

Por padrão, o delimitador é uma vírgula (,) e o qualificador da string é uma aspa dupla ("). Isso pode ser alterado especificando o segundo e o terceiro argumentos opcionais, respectivamente.

Exemplos

arr = SplitCSV('"Donald","Minnie ""The Mouse""", Goofy');
donald = arr[0];
// Returns "Donald"
minnie = arr[1];
// Returns "Minnie ""The Mouse"""
goofy = arr[2];
// Returns "Goofy"

StringLength

Declaração

int StringLength(string str)

array StringLength(array arr)

Sintaxe

StringLength(string str)

StringLength(array arr)

Parâmetros obrigatórios

• str: (Primeira forma) Uma string

• arr: (Segunda forma) Uma matriz

Descrição

Retorna o comprimento de uma string.

A função retorna um array se o argumento for um array, com cada elemento do array retornado com o comprimento do elemento correspondente do array do argumento. O Length A função retorna o comprimento de um array em vez do comprimento dos elementos individuais.

Exemplos

arr = {a="abcd", b="e"};

StringLength(arr);
// Returns the array {4,1}

Length(arr);
// Returns 2

ToLower

Declaração

string ToLower(string str)

Sintaxe

ToLower(<str>)

Parâmetros obrigatórios

• str: Uma sequência

Descrição

Converte todos os caracteres maiúsculos ASCII (A a Z, ASCII 65 a 90) em uma string para minúsculos.

Exemplos

ToLower("Hello World!");
// Returns "hello world!"

ToProper

Declaração

string ToProper(string str)

Sintaxe

ToProper(<str>)

Parâmetros obrigatórios

• str: Uma sequência

Descrição

Converte uma string para o caso adequado (a primeira letra de cada palavra sendo maiúscula). Isso é diferente do caso de título, que coloca em maiúscula apenas palavras selecionadas e mais longas em uma string.

s = "mccartney, paul";
s = Right( ToProper( " " + s), Length(s));

Exemplos

ToProper("bob dylan");
// Returns "Bob Dylan"
ToProper("arthur c. Clarke");
// Returns "Arthur C. Clarke"
ToProper("Peter o'toole");
// Returns "Peter O'Toole"

ToUpper

Declaração

string ToUpper(string <str>)

Sintaxe

ToUpper(<str>)

Parâmetros obrigatórios

• str: Uma sequência

Descrição

Converte todos os caracteres ASCII minúsculos (a a z, ASCII 97 a 122) em uma string para maiúsculo.

Exemplos

ToUpper("Hello World!");
// Returns "HELLO WORLD!"

Trim

Declaração

string Trim(string str)

Sintaxe

Trim(<str>)

Parâmetros obrigatórios

• str: Uma sequência

Descrição

Remove espaços em branco do início e do fim de uma string e retorna os caracteres restantes.

Exemplos

Trim(" Hello World! ");
// Returns "Hello World!"

TrimChars

Declaração

string TrimChars(string str, string trimChars)

Sintaxe

TrimChars(<str>, <trimChars>)

Parâmetros obrigatórios

• str: Uma corda a ser aparada
• trimChars: Uma sequência de caracteres de corte a serem correspondidos; a ordem não importa

Descrição

Remove quaisquer caracteres iniciais ou finais em uma string que correspondem aos caracteres de corte e retorna os caracteres restantes.

Esta função testa cada caractere inicial e final de uma string e verifica se ele é encontrado nos caracteres de corte. Se for, ele é removido e o processo é repetido até que não haja mais correspondências.

Isso pode ser usado para cortar caracteres diferentes dos caracteres de espaço em branco padrão, como cortar dois pontos.

Veja também o LTrimChars e RTrimChars funções.

Exemplos

TrimChars("::StartMsg :: Hello :: EndMsg::", ":");
// Returns "StartMsg :: Hello :: EndMsg"

TrimChars("/* This is a comment */", " /*");
// Returns "This is a comment"

Truncate

Declaração

string Truncate(string str, int firstChars, int lastChars)

Sintaxe

Truncate(<str>, <firstChars>, <lastChars>)

Parâmetros obrigatórios

• str: Uma sequência
• firstChars: O número de caracteres a serem excluídos da esquerda (o começo) da string
• lastChars: O número de caracteres a serem excluídos da direita (o fim) da string

Descrição

Apaga firstChar caracteres da esquerda (o começo) e lastChars caracteres da direita (o fim) de uma string e retorna a string restante.

Veja também o Left e Right funções.

Exemplos

Truncate("a,b,c,", 2, 1);
// Returns "b,c"

URLDecode

Declaração

string URLDecode(string url, string paramName)

Sintaxe

URLDecode(<url>, <paramName>)

Parâmetros obrigatórios

• url: Uma string contendo uma URL
• paramName: O nome de um parâmetro na URL cujo valor deve ser retornado

Descrição

Analisar uma string de URL e retornar o valor decodificado do parâmetro de URL com o nome especificado. O caso do nome é ignorado. Se o nome não for encontrado nos parâmetros da URL, uma string vazia ("") é retornado.

Veja também o ParseURL e URLEncode funções.

Exemplos

url = "http://hostname/user?email=john1990%40gmail.com&name=John%20Smith";
URLDecode(url, "name");
// Returns "John Smith"

URLEncode

Declaração

string URLEncode(string str[, int encodingOption])

Sintaxe

URLEncode(<str>[, <encodingOption>])

Parâmetros obrigatórios

• url: Uma string contendo um valor a ser codificado seguindo as regras de RFC 1738

Parâmetros opcionais

• encodingOption: Um inteiro (0 - 3) que especifica a codificação a ser usada. O valor padrão é 0. Veja a lista abaixo.

Descrição

Codifica uma string seguindo RFC 1738.

Os valores válidos para a opção de codificação opcional são:

• 0: Codificação de URL padrão. Codifica caracteres de controle ASCII, caracteres não ASCII, caracteres "reservados" e caracteres "inseguros". Esta é a codificação padrão se a opção for omitida.
• 1: Não codifique caracteres "inseguros": " \< ;> ; # % { } | \ ^ \~ [ ] ` and the space character
• 2: Don't encode "reserved" characters: ; / ? : @ & =
• 3: Don't encode "unsafe" characters and "reserved" characters

These characters are considered "safe" and are never encoded: $ - _. + ! * ' ( ) ,

See also the AnalisarURL and `Funções URLDecode.

Exemplos

value1 = "FIRST#"; value2 = "<LAST>";
url = "http://hostname/get_doc?" +
    "name1=" + URLEncode(value1) +
    "&name2=" + URLEncode(value2);
// Returns
// http://hostname/get_doc?name1=FIRST%23&name2=%3CLAST%3E