Funciones generales en Jitterbit Studio

Las funciones generales incluyen aquellas funciones que no son específicas de una interacción en particular, pero se pueden aplicar en casi cualquier script.

ArgumentList

Declaración

null ArgumentList(type var1[,... ])

Sintaxis

ArgumentList(<var1>[,... ])

Parámetros requeridos

• var1: Una variable local que se inicializará desde la lista de argumentos de la instancia que realiza la llamada

Parámetros opcionales

• var2,... varN: Variables adicionales que se inicializarán desde la lista de argumentos de la instancia que realiza la llamada

Descripción

Esta función inicializa un conjunto de variables locales desde su lista de argumentos.

La construcción de las variables locales depende de cuál de estos casos se aplique:

• Caso 1: Asignaciones de transformación Cuando se realiza la llamada a la función en la asignación de un campo de destino. (Debe haberse realizado una llamada anterior a la función SetInstances). Las variables locales se construyen a partir de las variables globales correspondientes en la instancia dada por la función SetInstances.
• Caso 2: Ejecución de un script Cuando se realiza la llamada a la función en un script. Las variables locales se construyen a partir de los argumentos correspondientes en la lista proporcionada por la declaración RunScript que realiza la llamada. También se puede acceder a estas variables por índice, como _1, _2...

Esta función devuelve un valor nulo que puede ignorarse. Como alternativa, consulta la función GetInstance.

Ejemplos

// Assuming a parent mapping contains these statements:
...
s = "SELECT key_name, key_value, key_type FROM key_values";
r = DBLookupAll("<TAG>endpoint:database/My Database</TAG>", s);
SetInstances("DETAILS", r);
...

// In the DETAILS target node, a field could
// have as a mapping:
<trans>
ArgumentList(key, value, type);
key + " = " + value + " (of type " + type + ")";
</trans>

// This code fragment calls a script
// "CalculateDisplayString":
...
RunScript("<TAG>script:CalculateDisplayString</TAG>", "John", 35);
// The result will be the string
// "John is 35 years old."
...

// The script "CalculateDisplayString", using
// names:
<trans>
ArgumentList(name, age);
name + " is " + age + " years old.";
</trans>

// Same script "CalculateDisplayString",
// using indices:
<trans>
// ArgumentList: name, age
_1 + " is " + _2 + " years old.";
</trans>

AutoNumber

Declaración

int AutoNumber()

Sintaxis

AutoNumber()

Descripción

Devuelve el número de una instancia dentro de una jerarquía en particular.

Ejemplos

Supón una arquitectura de destino con dos registros de nivel superior: PO1 y PO2:

• PO1 es un padre de tres registros secundarios: PO1_record1, PO1_record2 y PO1_record3.
• PO2 es un padre de dos registros secundarios: PO2_record1 y PO2_record2.

Cuando se llama a la función AutoNumber():

• AutoNumber() llamada al nivel principal devuelve 1 en PO1 y devuelve 2 en PO2.
• AutoNumber() al nivel secundario de PO1 devuelve 1 en PO1_record1, devuelve 2 en PO1_record2 y devuelve 3 en PO1_record3, ya que PO1 tiene 3 registros secundarios.

CancelOperation

Declaración

void CancelOperation(string operationInstanceGUID)

Sintaxis

CancelOperation(<operationInstanceGUID>)

Parámetros requeridos

• operationInstanceGUID: La ruta de referencia de cadena a la operación en el proyecto actual que se va a cancelar

Descripción

Cancela una operación en particular especificada por la ruta de referencia de la operación. Para obtener más información, consulta las instrucciones sobre cómo insertar operaciones en la sección Operaciones de Jitterbit Script.

Como se muestra en el ejemplo a continuación, llama a la función GetOperationQueue para recuperar instancias de operaciones en ejecución. El GUID de instancia de operación está en el índice 4 de los subarreglos devueltos por la función GetOperationQueue. Consulta la función GetOperationQueue para obtener detalles.

Ejemplos

// Cancel all instances of a particular
// operation
opt = "<TAG>operation:My Operation</TAG>";
queue = GetOperationQueue(opt);
n = Length(queue);
i = 0;
message = "Canceling operation instance: ";
While(i < n, op_inst = queue[i][4];
  WriteToOperationLog(message + op_inst);
  CancelOperation(op_inst);
  i++;
);

CancelOperationChain

Declaración

void CancelOperationChain(string message)

Sintaxis

CancelOperationChain(<message>)

Parámetros requeridos

• message: Si es una cadena no vacía, se registrará como un mensaje de advertencia en el registro de operaciones.

Descripción

Si la operación actual tiene operaciones de éxito o fracaso, llamar a este método hará que esas operaciones se cancelen. También se cancelarán todas las operaciones vinculadas por una condición. Sin embargo, todos los scripts en la operación actual se completarán.

Esto puede ser útil si una operación se ejecuta en un bucle y se ha alcanzado la condición para dejar de hacer bucles.

Ejemplos

CancelOperationChain("The success operation does not need to run.");

Eval

Declaración

string Eval(type expToEvaluate, type defaultResult)

Sintaxis

Eval(<expToEvaluate>, <defaultResult>)

Parámetros requeridos

• expToEvaluate: Una expresión a evaluar; si es válida, se devolverá su resultado
• defaultResult: Resultado predeterminado a evaluar y devolver si expToEvaluate no es válido

Descripción

Evalúa el primer argumento; si es válido, su resultado se devuelve como una cadena. De lo contrario, se evalúa el valor predeterminado y sus resultados se devuelven como una cadena.

Se puede usar como una instrucción "try-catch" ya que el segundo argumento se evaluará solo si el primero falla.

Ejemplos

// Returns a value of "100": the string
// representation of 4 multiplied by 25:
entry = Eval(4*25,"Bad Entry");

// Returns "Bad Entry", as strings cannot be
// multiplied:
book = "";
entry = Eval(book*36.4, "Bad Entry");

// Execute a SQL statement and terminate an operation if it fails:
results = Eval(
  DBLookup("<TAG>endpoint:database/My Database</TAG>",
    "SELECT col FROM table"),
  RaiseError("Failed to execute SQL statement: "
    + GetLastError())
);

Get

Declaración

type Get(string name)

type Get(string name[, int index1, int index2,... int indexN])

type Get(array name[, int index1, int index2,... int indexN])

Sintaxis

Get(<name>[, <index1>, <index2>,... <indexN>])

Parámetros requeridos

• name: El nombre de una variable global, ya sea un escalar o un arreglo, o un arreglo

Parámetros opcionales

• index1,... indexN: Índices que especifican el elemento deseado en el arreglo o un subarreglo

Descripción

Devuelve el valor de una variable global con un nombre dado. Si se le pasa un arreglo o el nombre de una variable global que es un arreglo, devuelve un elemento del arreglo. Consulta también la función complementaria Set.

Si el primer argumento es un arreglo o el nombre de una variable global que es un arreglo, la función recupera un elemento específico por su índice (o índices para un arreglo multidimensional como un conjunto de registros) usando los argumentos restantes.

Los arreglos están indexados desde cero; el primer elemento está en el índice 0 y el último elemento (del arreglo $array) está en el índice [Length($array)-1].

Si intenta recuperar un elemento más allá del final del arreglo, el valor devuelto será nulo.

Ejemplos

// Returns the value of the global variable "Count"
Get("Count");

// Returns the third element of an array (0-based)
Get($arr, 2);

// For arrays, this is the same as previous,
// as "arr" is equivalent to $arr in the case of arrays
Get("arr", 2);

// Returns the n-th element of the m-th array in $arr
Get($arr, m-1, n-1);

GetChunkDataElement

Declaración

type GetChunkDataElement(string name)

Sintaxis

GetChunkDataElement(<name>)

Parámetros requeridos

• name: El nombre de la variable de chunk

Descripción

Devuelve el valor de la variable de chunk con un nombre dado. Una variable de chunk se evalúa a medida que se procesa cada chunk de datos. Un método alternativo es utilizar la sintaxis SCOPE_CHUNK de la función Set. Consulta también las funciones SetChunkDataElement y Set.

Ejemplos

// If used in a transformation mapping, this sets
// the value of the chunk variable "CustomerFileName" to
// the results of a calculation using the value of the "Customer" field
// at the time of the chunking to create a filename for that chunk:

SetChunkDataElement("CustomerFilename", "customer_" + CustomerID + ".csv");

// This global variable would be available as a variable in the
// filenames field of the connection parameters of a target as:

[CustomerFilename]

// It would also be available in scripts in the same chunk as:

GetChunkDataElement("CustomerFilename");

// With each chunk created, a unique filename for that customer ID
// will be created, such as (depending on the values of CustomerID):
customer_1009.csv
customer_2019.csv
customer_5498.csv


// Returns the value of a chunk variable
result = GetChunkDataElement("Count");

GetHostByIP

Declaración

string GetHostByIP(string ipAddress)

Sintaxis

GetHostByIP(<ipAddress>)

Parámetros requeridos

• ipAddress: Una cadena con una dirección IP

Descripción

Resuelve una dirección IP a un nombre de host.

Ejemplos

GetHostByIP("127.0.0.1");

GetInputString

Declaración

string GetInputString(type arg)

Sintaxis

GetInputString(<arg>)

Parámetros requeridos

• arg: Una variable global

Descripción

Devuelve la entrada sin formato como una cadena dada una variable global de origen.

Esto es útil cuando la representación estándar de Jitterbit de un tipo de dato (como una fecha o un doble) no es adecuada y se requiere la entrada "sin procesar". Si se llama este método en un objeto que no es una variable global de origen, se devuelve una cadena vacía.

Ejemplos

// La entrada es demasiado grande para un doble de Jitterbit
// devuelve la entrada sin procesar en su lugar
$SessionId = GetInputString(root$transaction$body$GetMachineList$req$SessionID$)

GetLastOperationRunStartTime

Declaración

date GetLastOperationRunStartTime(string operationId)

Sintaxis

GetLastOperationRunStartTime(<operationId>)

Parámetros requeridos

• operationId: Una ruta de referencia de cadena a una operación en el proyecto actual

Descripción

Devuelve la última fecha y hora en que se ejecutó la operación indicada. El valor devuelto es una fecha (que incluye la fecha y la hora). Se debe utilizar solo con un único agente privado.

La operación utilizada en esta llamada de función debe estar definida como una operación en el proyecto actual. Para obtener más información, consulta las instrucciones sobre cómo insertar operaciones en la sección Operaciones en Jitterbit Script.

La fecha devuelta está en UTC (sin una zona horaria específica). Utiliza la función ConvertTimeZone para convertir a una hora local, como se ve en el ejemplo siguiente.

Ejemplos

op = "<TAG>operation:MyOperation</TAG>";
lastOpRun = GetLastOperationRunStartTime(op);
// Converting to a local time zone
$lorInMyTimeZone = ConvertTimeZone(lastOpRun,
    "UTC", "CST");

GetName

Declaración

string GetName(type arg)

Sintaxis

GetName(<arg>)

Parámetros requeridos

• arg: Una variable o variable global

Descripción

Devuelve el nombre de una variable o una variable global.

Ciertas funciones devuelven un arreglo de variables globales nombradas; si está definida, esta función recupera el nombre del valor.

Ejemplos

x = {a="var1", b="var2"};
GetName(x[0]);
// Returns the string "a"
GetName(x)[0];
// Also returns the string "a"

// The source is a simple text and [] represents the source element
values = GetSourceInstanceArray([]);
// Returns the first field name of the source element
GetName(values[0]);

GetOperationQueue

Declaración

array GetOperationQueue([string operationTag])

Sintaxis

GetOperationQueue([<operationTag>])

Parámetros opcionales

• operationTag: Una ruta de referencia de cadena a una operación en el proyecto actual; de lo contrario, se utilizan todas las operaciones del proyecto actual

Descripción

Devuelve el contenido de la cola de operaciones como un arreglo. Solo se devuelven las operaciones para las que el usuario actual tiene acceso de lectura. Para utilizarse solo con un único agente privado.

El resultado se devuelve como un arreglo de arreglos, con estos elementos en cada subarreglo:

• 0: GUID de operación (cadena)
• 1: La bandera IsExecuting (booleano)
• 2: Marca de tiempo (fecha) de cuando la operación se agregó a la cola
• 3: Segundos en estado actual (entero)
• 4: GUID de instancia de operación (cadena)
• 5: Nombre de operación (cadena)

El argumento de etiqueta de operación es opcional. Si el argumento de etiqueta de operación está presente, solo se devolverán entradas de cola para esa operación en particular. Para obtener más información, consulta las instrucciones sobre cómo insertar operaciones en la sección Operaciones en Jitterbit Script.

Ejemplos

// Write the queue for a particular operation to
// the operation log:
op = "<TAG>operation:MyOperation</TAG>";
queue = GetOperationQueue(op);
n = Length(queue);
i = 0;
// Loop over the queue entries
While(i < n,
  WriteToOperationLog("Queue Entry: "
    + "GUID=" + queue[i][0]
    + "; IsExecuting=" + queue[i][1]
    + "; Added at: " + queue[i][2]);
  i++;
);

GetServerName

Declaración

string GetServerName()

Sintaxis

GetServerName()

Descripción

Devuelve el nombre de la máquina en la que se ejecuta el agente.

Ejemplos

GetServerName();
// Devuelve el nombre del servidor

GUID

Declaración

string GUID()

Sintaxis

GUID()

Descripción

Devuelve una cadena GUID (un identificador único global, también conocido como identificador único universal o UUID).

El formato del GUID es xxxxxxxx-xxxx-Mxxx-Nxxx-xxxxxxxxxxxx, donde M es la versión (4) y N es la variante (8).

Ejemplos

GUID();
// Devuelve una cadena como "c056f89d-1f45-458e-8b25-9ecf2ed10842"

IfEmpty

Declaración

type IfEmpty(type arg, type default)

Sintaxis

IfEmpty(<arg>, <default>)

Parámetros requeridos

• arg: Un argumento a evaluar para ver si es nulo o una cadena vacía
• default: Valor predeterminado a devolver si arg es nulo o una cadena vacía

Descripción

Devuelve el valor predeterminado si el primer argumento es nulo o si la representación de cadena del argumento es una cadena vacía. De lo contrario, devuelve el primer argumento. Esta es una forma abreviada de una declaración de función If:

If(IsNull(arg)| |Length(arg)==0, default, arg)

Consulta también la función IsNull.

Ejemplos

// Si la variable "myDate" es nula o está vacía,
// devuelve la fecha actual; de lo contrario, devuelve "myDate"
result = IfEmpty(myDate, Now());

IfNull

Declaración

type IfNull(type arg, type default)

Sintaxis

IfNull(<arg>, <default>)

Parámetros requeridos

• arg: Un argumento para evaluar si es nulo
• default: Valor predeterminado a devolver si arg es nulo

Descripción

Devuelve el valor predeterminado si el primer argumento es nulo; de lo contrario, devuelve el primer argumento.

Se trata de un atajo para una declaración de función If:

If(IsNull(arg), default, arg)

Consulta también las funciones IsNull e IfEmpty.

Ejemplos

// Si la variable "myDate" es nula,
// devuelve la fecha actual; de lo contrario, devuelve "myDate"
result = IfNull(myDate, Now());

InitCounter

Declaración

long InitCounter(type counter[, long initialValue])

Sintaxis

InitCounter(<counter>, <initialValue>)

Parámetros requeridos

• counter: El nombre de una variable o una referencia a una variable global que se usará como contador

Parámetros opcionales

• initialValue: El valor inicial para establecer el contador; el valor predeterminado es 0

Descripción

Inicializa un contador, opcionalmente pasando un valor inicial. Debe usarse con un solo agente. Si no se establece un valor inicial, se establece en 0. El primer argumento es el nombre de una variable o una referencia a una variable (consulta los ejemplos). Este método debe llamarse solo en contextos de un solo hilo. Llamar a este método en un contexto multihilo resultará en un error. Consulta también Usar variables con chunking en Opciones de operación.

Ejemplos

// Initialize counter to 0 using the name of a global variable
InitCounter("counter");

// Initialize counter to 100 using a reference to a global variable
InitCounter($counter, 100);

InList

Declaración

int InList(type x[, type arg1, ... type argN])

Tipos de datos compatibles para type

int, float, long, double, string, bool, date, binary, collection, map

Sintaxis

InList(<x>[, <arg1>, ... <argN>])

Parámetros requeridos

• x: Un elemento a comparar para encontrar una coincidencia

Parámetros opcionales

• arg1...argN: Una serie de argumentos contra los que se comparará x

Descripción

Comprueba si x está en la lista de argumentos (arg1 hasta argN). Si se encuentra una coincidencia (por valor), esta función devuelve un número entero que representa la posición de la coincidencia en la lista, siendo la primera posición representada por el número entero 1.

Si la lista contiene más de una instancia de x, esta función devuelve la posición de la primera coincidencia (la coincidencia con el índice de posición más bajo). Se devuelve 0 si la lista no contiene un valor coincidente o si se suministra solo un argumento.

Ejemplos

InList("x","a","b","c","x");
// Returns 4

InList("a","a","b","c","a");
// Returns 1

InList("x","a","b","c");
// Returns 0

InList("x");
// Returns 0

InList("1", 123, "12", true);
// Returns 3 due to implicit conversion

IsInteger

Declaración

bool IsInteger(type x)

Sintaxis

IsInteger(<x>)

Parámetros requeridos

• x: Un elemento a ser evaluado

Descripción

Devuelve verdadero si el argumento es de tipo entero o largo, o se puede convertir a un entero o largo sin pérdida de información.

Ejemplos

$s="1";
IsInteger($s);
// Returns true
$s="1a";
IsInteger($s);
// Returns false
$s=12.12;
IsInteger($s);
// Returns false
$s=12.00;
IsInteger($s);
// Returns true

IsNull

Declaración

bool IsNull(type x)

Sintaxis

IsNull(<x>)

Parámetros requeridos

• x: Un elemento a ser evaluado

Descripción

Devuelve verdadero si el argumento es nulo. Se aplica a campos de base de datos, variables y funciones que pueden devolver valores nulos.

Consulta también las funciones IfNull e IfEmpty para accesos directos que se pueden usar en lugar de esta función.

Para solucionar problemas, consulta IsNull devuelve falso para cadenas vacías de datos de origen JSON en la guía de solución de problemas de operaciones.

Ejemplos

// Si "POHeader.Vendor_Code" es nulo,
// devuelve la cadena "VC", de lo contrario devuelve el código
If(IsNull(POHeader.Vendor_Code), POHeader.Vendor_Code, "VC")

IsValid

Declaración

bool IsValid(type x)

Sintaxis

IsValid(<x>)

Parámetros requeridos

• x: Un elemento a ser evaluado

Descripción

Devuelve verdadero si la evaluación del argumento se realiza sin errores.

Ejemplos

IsValid(Date("abc"))
// Returns false, since the string "abc"
// cannot be successfully converted to a date

IsValid(3/0)
// Returns false, since division by 0
// is not permitted

IsValid(0/3)
// Returns true, since 0/3 is a legal expression
// evaluating to 0

Length

Declaración

int Length(type x)

Sintaxis

Length(<x>)

Parámetros requeridos

• x: Un elemento a ser evaluado

Descripción

Devuelve la longitud del argumento de entrada.

El comportamiento de este método depende del tipo de argumento:

• cadena: se devuelve la longitud de la cadena
• matriz: se devuelve el número de elementos en la matriz
• datos binarios: se devuelve el número de bytes
• Para todos los demás tipos, se intenta convertir el argumento a una cadena y se devuelve la longitud de la cadena resultante.
• Si no se puede convertir el argumento a una cadena, o el argumento es nulo o de tipo desconocido, se devuelve 0.

Ejemplos

// String length:
Length("Mississippi"); // returns 11

// Array length:
// Count the number of email address nodes
$nodes = SelectNodesFromXMLAny("cust:EmailAddress", Customer$Any#.,
"cust=urn:xmlns:25hoursaday-com:customer");
Length($nodes);

// Binary arguments:
Length(HexToBinary("b2082fee"));
// Returns 4, because the input is a 4-byte binary value

// Numeric arguments:
Length(1234567); // Returns 7
Length(123.45678); // Returns 9

// Miscellaneous:
Length(true); // Returns 1
Length(Now()); // Returns 19 since the default date format is "yyyy-MM-DD hh:mm:ss"
Length(Null()); // Returns 0

Null

Declaración

null Null()

Sintaxis

Null()

Descripción

Devuelve null.

Ejemplos

Esta función se puede utilizar para insertar un valor null en columnas específicas de una base de datos.

Random

Declaración

int Random(int min, int max)

Sintaxis

Random(<min>, <max>)

Parámetros requeridos

• min: Valor entero del número aleatorio mínimo
• max: Valor entero del número aleatorio máximo

Descripción

Genera un número entero aleatorio entre los valores mínimo y máximo proporcionados, inclusive. Consulta también la función RandomString.

Ejemplos

// Creates a random number from 0 to 9999999 (inclusive)
Random(0, 9999999);


// Creates a random number from 1 to 10
Random(1, 10);
// Returns a random 7-character string
// using the characters "0123456789"
RandomString(7, "0123456789");

// Returns a random 5-digit hexadecimal string
RandomString(5, "0123456789ABCDEF");

// Returns a random 7-digit integer string
// with no leading zeroes
RandomString(1, "123456789") +
  RandomString(6, "0123456789");

RandomString

Declaración

string RandomString(int len[, string chars])

Sintaxis

RandomString(<len>[, <chars>])

Parámetros requeridos

• len: Longitud de la cadena aleatoria resultante

Parámetros opcionales

• chars: Cadena que contiene caracteres que se utilizarán en la cadena aleatoria resultante

Descripción

Genera una cadena aleatoria de la longitud dada. Por defecto, la función utiliza caracteres alfanuméricos; el conjunto que incluye a-z, A-Z y 0-9. Consulta también la función Random.

Ejemplos

// Creates a random 5-digit hexadecimal string
RandomString(5, "0123456789ABCDEF");

// Creates a random 7-digit integer string
// with no leading zeroes
RandomString(1, "123456789") + RandomString(6, "0123456789");

ReadArrayString

Declaración

array ReadArrayString(string arrayString[, string type])

Sintaxis

ReadArrayString(<arrayString>[, <type>])

Parámetros requeridos

• arrayString: Una representación de cadena de un arreglo

Parámetros opcionales

• type: Una cadena que describe el tipo que representa la cadena del arreglo, como "string", "int", "double", "bool"

Descripción

Lee una cadena que representa un arreglo unidimensional o multidimensional.

El arreglo se representa encerrando los elementos del arreglo con un par de llaves ('{' y '}'). Cada elemento del arreglo puede ser un arreglo o un elemento escalar separado por coma (','). Los elementos de un arreglo deben ser todos escalares o todos arreglos.

El valor escalar se puede representar mediante una cadena CSV. Las comillas dobles para encerrar la cadena son opcionales, a menos que la cadena contenga caracteres especiales como ",{}\n (comillas dobles, coma, llaves, tabulaciones, saltos de línea o retornos de carro). Dentro de la cadena entre comillas dobles, cada comilla doble debe escaparse con dos comillas dobles. El segundo argumento opcional sirve para especificar el tipo de datos del valor escalar. Se asume que el tipo es cadena si no se especifica explícitamente.

Ejemplos

// One-dimensional array with four string values
ReadArrayString("{John,Steve,Dave,Eric}");

// One-dimensional array with three boolean values
ReadArrayString("{1,0,1}", "bool");

// Two-dimensional array
// The first array element is an array with three string values
// The second array element is an array with two string values
// The second element of the second array contains a trailing line break
ReadArrayString('{{abc,"a,b","a""b"},{"de","d
"}}');

RecordCount

Declaración

int RecordCount()

Sintaxis

RecordCount()

Descripción

Devuelve el número de instancia del bucle de destino que se está generando actualmente.

Si se invoca en una condición, devuelve el número de instancia de la última instancia que se generó. La primera vez que se invoca este método en un bucle, devuelve 0 (cero) si se invoca en una condición; de lo contrario, devuelve 1 (uno). El contador se reinicia a 0 cada vez que se inicia un nuevo bucle.

Ejemplos

RecordCount() devuelve un valor de 5 al generar la quinta línea en un nodo de bucle de destino.

ReRunOperation

Declaración

bool ReRunOperation([bool runSynchronously])

Sintaxis

ReRunOperation([<runSynchronously>])

Parámetros opcionales

• runSynchronously: Bandera que indica si la operación debe ejecutarse de forma sincrónica (valor predeterminado) o asincrónica

Descripción

Ejecuta nuevamente la operación actual.

El comportamiento de este método con respecto al valor de retorno y las variables globales es idéntico al de la función RunOperation. Consulta esa función para obtener una descripción de cómo la ejecución sincrónica o asincrónica de la operación afecta las variables globales.

Ejemplos

ReRunOperation();
// Re-runs the current operation synchronously
ReRunOperation(false);
// Re-runs the current operation asynchronously

RunOperation

Declaración

bool RunOperation(string operationId[, bool runSynchronously])

Sintaxis

RunOperation(<operationId>[, <runSynchronously>])

Parámetros requeridos

• operationId: Una ruta de referencia de cadena a una operación en el proyecto actual

Parámetros opcionales

• runSynchronously: Bandera que indica si la operación debe ejecutarse de forma sincrónica (valor predeterminado) o asincrónica

Descripción

Invoca una operación de forma sincrónica o asincrónica, siendo sincrónica la predeterminada.

La operación utilizada en esta llamada de función debe estar definida como una operación en el proyecto actual. Para obtener más información, consulta las instrucciones sobre inserción de operaciones en la sección Operaciones en Jitterbit Script.

Sincronía

Si run_synchronously es true, la operación o cadena de operaciones invocada (secundaria) se ejecutará secuencialmente desde la operación (principal) que la invoca. Todas las variables globales se heredan por la operación secundaria y cualquier cambio en las variables globales se reflejará en la operación principal. Este es el comportamiento predeterminado si no se proporciona el segundo argumento. Devuelve false si la operación invocada resultó en un error.

Si run_synchronously es false, la operación o cadena de operaciones invocada (secundaria) se ejecutará simultáneamente con la operación (principal) que la invoca. La operación invocada se añade a la cola de procesamiento de Jitterbit para ser procesada una vez que se hayan procesado las operaciones que la preceden. Todas las variables globales se heredan por la operación secundaria pero los cambios en esas variables no se reflejarán en la operación principal. La operación principal continuará ejecutándose independientemente de la operación secundaria y no hay garantía sobre cuál operación finalizará primero. Devuelve false si la operación secundaria no pudo añadirse a la cola. Con el modo asincrónico, estas variables globales se pasan a la operación invocada por valor en lugar de por referencia, lo que garantiza que cualquier cambio en las variables no se refleje en ninguna otra operación.

Para obtener más información, consulta Sincronicidad tal como se describe para la herramienta Invocar operación.

Si la función devuelve false para indicar un fallo o si no se pudo poner en cola la operación llamada, llama a GetLastError para recuperar el mensaje de error.

Ejemplos

// Runs the "MyOp"
RunOperation("<TAG>operation:MyOp</TAG>");

Véalo en la práctica

• Encadenar y controlar operaciones: Usar la herramienta Invocar operación o RunOperation en un script de controlador para vincular operaciones.
• Administrar operaciones asincrónicas: Cuándo usar la marca asincrónica y cómo evitar condiciones de carrera.
• Reintentar una operación fallida: Llamar a RunOperation dentro de un bucle While para reintentar en caso de fallo.
• Enrutar mensajes XML por tipo de nodo: Inspeccionar una carga útil entrante en un script de enrutador y llamar a la operación que coincida con el tipo de mensaje.

RunPlugin

Declaración

bool RunPlugin(string pluginId)

Sintaxis

RunPlugin(<pluginId>)

Parámetros requeridos

• pluginId: Una ruta de referencia de cadena a un complemento en el proyecto actual

Descripción

Ejecuta un complemento especificado y luego continúa la ejecución del script actual. Si se instalan varias versiones de un complemento en un agente, se utiliza la versión más reciente disponible.

En la interfaz de usuario de Studio, solo se muestran aquellos complementos que pueden ejecutarse dentro de un script; los complementos que se ejecutan en actividades están ocultos. Para obtener más información, consulta las instrucciones sobre cómo insertar complementos en la sección Complementos en Jitterbit Script.

Devuelve true si el complemento se completa sin errores. Devuelve false si no se pudo ejecutar el complemento o la implementación del complemento en sí devolvió un error. Llama a GetLastError para recuperar el mensaje de error.

Ejemplos

// Runs the Jitterbit HMACSHA1Generator plugin
RunPlugin("<TAG>plugin:http://www.jitterbit.com/plugins/pipeline/user/HMACSHA1Generator</TAG>");

RunScript

Declaración

string RunScript(string scriptId[, type var1, type var2, ..., type varN])

Sintaxis

RunScript(<scriptId>[, <var1>, <var2>, ..., <varN>])

Parámetros obligatorios

• scriptId: Una ruta de referencia de cadena a un script en el proyecto actual

Parámetros opcionales

• var1...varN: Variables adicionales, que se pasarán al script que se está llamando

Descripción

Ejecuta el script especificado y luego continúa la ejecución del script actual. Este método devuelve, si es exitoso, el valor devuelto del script llamado como una cadena.

El script utilizado en esta llamada de función debe definirse como un Jitterbit Script o JavaScript en el proyecto actual. Para obtener más información, consulta las instrucciones sobre cómo insertar scripts en Jitterbit Script o JavaScript.

Se puede pasar una lista de valores a una función RunScript como variables de entrada. El script creará variables locales usando estos valores con nombres predeterminados como _1, _2 ....

Si se prefieren nombres más descriptivos, se puede usar la función ArgumentList para asignar una lista de nombres de variables locales a la lista de _1, _2 .... Consulta la función ArgumentList para ver ejemplos.

Ejemplos

// Runs the script "CalculateStuff"
RunScript("<TAG>script:CalculateStuff</TAG>");

RunScript("<TAG>script:CalculateStuff</TAG>",
   "abc", 1);

// Sends the script "CalculateStuff" the
// string "abc" and the number 1
// Inside "CalculateStuff", these will be
// available as _1 and _2

Set

Declaración

type Set(string name, type value)

type Set(string name, type value, int index1[, int index2, ..., int indexN])

type Set(array name, type value, int index1[, int index2, ..., int indexN])

Sintaxis

Set(<name>, <value>[, <index1>, <index2>, ..., <indexN>])

Parámetros obligatorios

• name: El nombre de una variable global, ya sea un escalar o un arreglo
• value: Un valor que se asignará a la variable global

Parámetros opcionales

• index1...indexN: Índice o índices utilizados para describir la posición de un elemento si se establece un elemento en un arreglo

Descripción

Establece el valor de una variable global con un nombre dado a un valor y devuelve ese valor. Consulta también la función complementaria Get.

Primera forma: escalares

En la primera forma, se establece un nombre de cadena de una variable global usando el nombre y el valor proporcionados.

(Aunque se puede pasar una variable local como referencia, no se recomienda ya que los resultados pueden ser inconsistentes. Las variables locales no están diseñadas para establecerse a través de este mecanismo.)

Consulta los ejemplos a continuación.

Segunda y tercera formas: arreglos

En la segunda y tercera formas, argumentos adicionales proporcionan los índices para establecer un elemento en un arreglo.

Si el primer argumento es una matriz (o el nombre de una variable global que es una matriz), se puede establecer el valor de un elemento de la matriz especificando su índice (o índices para matrices multidimensionales) como argumentos adicionales.

Para agregar datos a una matriz, pasa un valor de índice negativo o el tamaño de la matriz. El tamaño se puede determinar usando la función Length como Length($array).

Las matrices tienen índice cero; el primer elemento está en el índice 0 y el último elemento (de la matriz $array) está en el índice [Length($array)-1]. Las matrices se pueden crear con las funciones Array o ReadArrayString.

Si intentas establecer un elemento más allá del final de la matriz, se agregarán elementos con valor nulo adicionales a la matriz según sea necesario para rellenarla al tamaño correcto.

Sintaxis del prefijo SCOPE_CHUNK

Establecer un nombre de variable que tenga el prefijo SCOPE_CHUNK creará una variable global que se evalúa conforme se procesa cada bloque de datos. Esto se puede usar para crear variables globales cuyo valor es único para un bloque particular, y luego puede identificar ese bloque cuando se crea un nombre de archivo o un registro en un destino. Consulta también las funciones GetChunkDataElement y SetChunkDataElement como método alternativo que permite usar otros nombres de variables.

Consulta ejemplos adicionales de uso de SCOPE_CHUNK para dividir datos CSV planos o datos JSON jerárquicos en Dividir un archivo en registros individuales.

Ejemplos

// Scalars:
// All of these forms are equivalent:
// they increase the global variable "count" by 1
result1 = Set("count", Get("count")+1);
$count++;
$count = $count + 1;

// Arrays:
// Appending a value to the array "arr"
// These are equivalent
Set($arr, "value", -1);
Set($arr, "value", Length($arr));

// Set the n:th entry in an array "arr"
// to the string "value"
Set($arr, "value", n-1);

// Set the n:th entry of the m:th array
// of "record_set"
Set($record_set, "value", m-1, n-1);

// SCOPE_CHUNK Prefix:
// Example from a mapping using the SCOPE_CHUNK syntax to
// create a global variable that is unique in value to a
// particular chunk.
// It uses the field "CustomerID" to identify the chunk:

Set("SCOPE_CHUNK_CustomerID",
    "customer_"+CustomerID+".csv");

// This variable will be available in the filenames field of
// the connection parameters of a target as:

[SCOPE_CHUNK_CustomerID]

// With each chunk created, a unique filename for that
// customer ID will be created, such as (depending on the
// values of Customer ID):
customer_1009.csv
customer_2019.csv
customer_5498.csv

SetChunkDataElement

Declaración

type SetChunkDataElement(string name, type value)

Sintaxis

SetChunkDataElement(<name>, <value>)

Parámetros obligatorios

• name: El nombre de la variable de bloque
• value: El valor a establecer para la variable de bloque

Descripción

Establece el valor de una variable de bloque especificada y devuelve el valor. Una variable de bloque se evalúa conforme se procesa cada bloque de datos. Un método alternativo es usar la sintaxis SCOPE_CHUNK de la función Set.

Consulta también las funciones GetChunkDataElement y Set.

Ejemplos

// If used in a transformation mapping, this sets
// the value of the chunk variable "CustomerFileName"
// to the results of a calculation using the value of
// the "Customer" field at the time of the chunking
// to create a filename for that chunk:

SetChunkDataElement("CustomerFilename",
    "customer_"+CustomerID+".csv");

// This global variable would be available as a
// variable in the filenames field of the connection
// parameters of a target as:

[CustomerFilename]

// It would also be available in scripts in the same
// chunk as:

GetChunkDataElement("CustomerFilename");

// With each chunk created, a unique filename for that
// customer ID will be created, such as (depending on
// the values of Customer ID):
customer_1009.csv
customer_2019.csv
customer_5498.csv

Sleep

Declaración

void Sleep(int seconds)

Sintaxis

Sleep(<seconds>)

Parámetros obligatorios

• seconds: El número entero de segundos para suspender la operación actual

Descripción

Suspende la ejecución durante un número de segundos especificado.

Ejemplos

// Suspende la operación actual durante 1 minuto
Sleep(60);

SourceInstanceCount

Declaración

int SourceInstanceCount()

Sintaxis

SourceInstanceCount()

Descripción

Devuelve el conteo de instancias del generador más reciente.

El valor es independiente de si se ha generado la instancia de destino o no; se devuelve el mismo valor si se llama en un script de condición o en un script de mapeo.

Cuando la primera instancia de origen se usa como generador, se devuelve 1, luego 2, y así sucesivamente.

Consulta también la función TargetInstanceCount.

Consulta un ejemplo adicional de uso de SourceInstanceCount en Dividir un archivo en registros individuales usando SourceInstanceCount.

Ejemplos

// Returns the instance count of the most recent generator
currentSourceInstance = SourceInstanceCount();

TargetInstanceCount

Declaración

int TargetInstanceCount()

Sintaxis

TargetInstanceCount()

Descripción

Devuelve el recuento de instancias de un nodo de bucle de destino generador.

Cuando se invoca en una condición, devuelve el número de instancias de destino que se han generado hasta ahora para el nodo de bucle actual. El número devuelto por este método será uno menos si se invoca en una condición, ya que en una condición no se sabe si la instancia de destino actual se generará o no.

Cuando se genera la primera instancia de destino, se devuelve 1, luego 2, y así sucesivamente. Si se invoca en una condición, la secuencia será en su lugar 0, 1, y así sucesivamente.

Consulta también la función SourceInstanceCount.

Ejemplos

// Returns the instance count of the most recent target generator
currentTargetInstance = TargetInstanceCount();

WaitForOperation

Declaración

void WaitForOperation(string operationId[, int timeOutSec, int pollIntervalSec])

Sintaxis

WaitForOperation(<operationId>[, <timeOutSec>, <pollIntervalSec>])

Parámetros requeridos

• operationID: Una ruta de referencia de cadena a una operación en el proyecto actual

Parámetros opcionales

• timeOutSec: Una variable local
• pollIntervalSec: Una variable local

Descripción

Detiene la ejecución de un script o mapeo hasta que todas las instancias de la operación especificada actualmente en la cola de operaciones terminen el procesamiento. Este método es útil si deseas agregar muchas instancias de una operación a la cola para procesamiento paralelo y luego esperar a que todas terminen.

La operación utilizada en esta llamada de función debe definirse como una operación en el proyecto actual. Para más información, consulta las instrucciones sobre cómo insertar operaciones en la sección Operations en Jitterbit Script.

Nota:

• Para cada operación (identificada por su operationID) que se debe esperar, debe realizarse una llamada a este método.
• Las instancias de operación que se agregan (mediante llamadas a la función RunOperation) después de que se realice esta llamada no se esperan.
• El usuario actual necesita tener acceso de lectura para la operación que se está esperando.

El segundo argumento (opcional) es el tiempo de espera en segundos. El tiempo de espera predeterminado es de 1 hora (3600 segundos) y si todas las operaciones no han terminado dentro de este tiempo, se lanzará un error. Si esperas que tus operaciones se ejecuten durante más tiempo en condiciones normales, debes aumentar el tiempo de espera. Puedes manejar este error usando la función Eval.

El tercer argumento (opcional) es el intervalo de sondeo en segundos. El intervalo de sondeo es el tiempo entre comprobaciones de la cola de operaciones. El intervalo de sondeo predeterminado es de 10 segundos. El valor predeterminado no será un impacto significativo en el rendimiento, pero si se espera que tus operaciones se ejecuten durante un tiempo muy largo, quizás desees aumentar el intervalo de sondeo.

Ejemplos

// Add ten operation instances to the queue
// and wait for all of them to finish
i = 0;
while(i < 10,
  RunOperation("<TAG>operation:MyOperation</TAG>", false);
  i++;
);

WaitForOperation("<TAG>operation:MyOperation</TAG>");